Bei einer erweiterten Suche können Sie strukturierte Abfragen verwenden, um in coLAB nach Inhalten zu suchen.



Verwenden von CQL


Bei einer erweiterten Suche können Sie strukturierte Abfragen verwenden, um in coLAB nach Inhalten zu suchen.

Wenn Sie eine erweiterte Suche durchführen, verwenden Sie die Confluence Query Language (CQL).

Eine einfache Abfrage in CQL (auch als "Klausel" bezeichnet) besteht aus einem Feld, gefolgt von einem Operator, gefolgt von einem oder mehreren Werten oder Funktionen.

Die folgende einfache Abfrage findet beispielsweise den gesamten Inhalt im Bereich "HELP". Es verwendet das Bereichsfeld, den = Operator und den Wert "HELP".)


space = "HELP"


Um zur erweiterten Suche zu gelangen klicken Sie rechts oben auf die Suche und danach auf Erweiterte Suche






Suchfunktion - Händisch

CQL-Abfragen können nun in der Leiste oben eingegeben werden, klicken Sie anschließend auf CQL Search um Ihre Abfrage abzusenden. In diesem Fall wird nach dem Typ Seite im Bereich TU coLAB Hilfe gesucht. Alternativ kann für viele Anwendungsfälle auch die vereinfachte vorgefertigte Funktion links benützt werden.



Suchfunktion - Vereinfacht

In der linken Seite sehen Sie einige Felder, die Sie ausfüllen können um eine CQL-Abfrage zu starten. Wenn Sie im Bereich TU coLAB Hilfe auswählen und Vom Typ den Typ Seiten auswählen erzielen Sie dasselbe Ergebnis wie das Bild auf der linken Seite. Wenn Sie die Funktionalität weiter unten auf der Seite sehen, werden Sie feststellen, dass manche komplexeren Fälle leichter per Hand zu schreiben sind als mit der vereinfachten Funktion. Nichtsdestotrotz ist diese Funktion für einfachere Fälle sehr zu empfehlen.



CQL Search Makro

  1. Fügen Sie das Makro CQL Search auf Ihre Seite ein.

  2. Geben Sie die Parameter ein:

    ParameterBeschreibung
    CQLGeben Sie hier Ihre CQL-Abfrage ein zu denen Sie die Ergebnisse auf Ihrer Seite einbetten möchten.
    Max. resultsWie viele Ergebnisse sollen pro Seite ausgegeben werden.


  3. Speichern Sie das Makro und aktualisieren Sie die Seite.

Im Beispiel rechts lautet die CQL-Abfrage: 

space = help AND label = "colabhilfe"



Verwendbare Attribute


Liste der Keywörter

KeywörterBedeutungBeispiele
AND

Wird verwendet, um mehrere Klauseln mit UND zu kombinieren.

Die sogenannte Konjunktion AND bedeutet, dass jede gelistete Klausel erfüllt werden muss. 

Beispiel: Ich möchte Seiten sowohl mit dem Stichwort A als auch dem Stichwort B.


label = "colabhilfe" AND type = page

type = page AND creator = "lukas.ortner@tuwien.ac.at"

mention = "lukas.ortner@tuwien.ac.at" AND creator != "lukas.ortner@tuwien.ac.at"


OR

Wird verwendet, um mehrere Klauseln mit ODER zu kombinieren.

Die sogenannte Disjunktion OR bedeutet, dass eines der gelisteten Klausel ausreicht, um ein Resultat zu ergattern.

Beispiel: Ich möchte Seiten mit dem Stichwort A oder B. Es reicht, wenn eine Seite eine Klausel erfüllt um in meinen Ergebnissen aufzutauchen.

Für mehrere OR-Klauseln sehen Sie sich den Operator IN weiter unten an.


label = "colabhilfe" OR label = "sprechstunde"


NOT

Wird verwendet, um einzelne Klauseln oder eine komplexe CQL-Abfrage (eine Abfrage, die aus mehr als einer Klausel besteht) in Klammern zu negieren.


space = help AND NOT creator = "lukas.ortner@tuwien.ac.at" AND NOT label ="colabhilfe"


ORDER BY

Wird verwendet, um die Felder anzugeben, nach deren Werten die Suchergebnisse sortiert werden.

Standardmäßig wird die eigene Sortierreihenfolge des Feldes verwendet. Sie können dies überschreiben, indem Sie aufsteigende Reihenfolge ("asc") oder absteigende Reihenfolge ("desc") angeben.


Nicht alle Felder unterstützen die Sortierung. Im Allgemeinen wird die Reihenfolge nicht unterstützt, wenn ein Inhalt mehrere Werte für ein Feld haben kann. Beispielsweise wird die Reihenfolge bei Stichwörtern nicht unterstützt.


space = help ORDER BY created

space = help ORDER BY created desc

creator = "lukas.ortner@tuwien.ac.at" ORDER BY created desc



Liste der Operator

NameOperatorBeschreibungBeispiel
Gleich=

Der = Operator wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds genau mit angegebenem Wert übereinstimmt.

Kann nicht mit Textfeldern verwendet werden. Siehe Operator Vorhanden in



space = HELP

Inhalt aus dem Bereich mit dem Bereichsschlüssel HELP


Nicht gleich!=

Der != Operator wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds nicht mit angegebenen Wert übereinstimmt.

Kann nicht mit Textfeldern verwendet werden. Siehe Operator Nicht vorhanden in



space = HELP AND label != "colabhilfe"

Inhalt aus dem Bereich TU coLAB Hilfe die nicht das Stichwort "colabhilfe" tragen


Größer als>

Der Operator > wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds größer als der angegebene Wert ist.

Kann nicht mit Textfeldern verwendet werden. Anwendbar auf Datumsfelder und numerische Felder.



created > now("-2w")

Jeglicher Inhalt, der in den letzten 2 Wochen erstellt worden ist.


Größer gleich>=

Der Operator >= wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds größer gleich als der angegebene Wert ist.

Kann nicht mit Textfeldern verwendet werden. Anwendbar auf Datumsfelder und numerische Felder.



created >= "2020/12/31" AND type = page

Alle Seiten, die seit 31.12.2020 erstellt worden sind.


Kleiner als<

Der Operator < wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds kleiner als der angegebene Wert ist.

Kann nicht mit Textfeldern verwendet werden. Anwendbar auf Datumsfelder und numerische Felder.



lastModified < startOfYear() AND type = page

Alle Seiten, die vor Beginn dieses Jahres erstellt worden sind.


Kleiner gleich als<=

Der Operator <= wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds kleiner gleich als der angegebene Wert ist.

Kann nicht mit Textfeldern verwendet werden. Anwendbar auf Datumsfelder und numerische Felder.



created <= "2020/05/31" AND type = blogpost

Alle Blogeinträge, die vor Juni 2020 erstellt worden sind.



Vorhanden in IN

Der Operator IN wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds einer von mehreren angegebenen Werten ist.

Die Werte werden als eine, durch Komma getrennte, Liste angegeben, die von Klammern umgeben ist.

Die Verwendung von IN entspricht der Verwendung mehreren Ist-Gleich (=) Anweisungen mit dem Schlüsselwort OR. Es ist jedoch kürzer und einfacher.




contributor IN ("lukas.ortner@tuwien.ac.at","michaela.dereani@tuwien.ac.at", "kurt.rosivatz@tuwien.ac.at") AND space = HELP AND type = page

Alle Seiten aus dem Bereich TU coLAB Hilfe bei denen folgende 3 Nutzer_innen einen Beitrag zu einer Seite geleistet haben.



Nicht vorhanden inNOT IN

Der Operator NOT IN wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds nicht einer von mehreren angegebenen Werten ist.

Die Verwendung von NOT IN entspricht der Verwendung mehreren Ist-Gleich (=) Anweisungen mit dem Schlüsselwort OR. Es ist jedoch kürzer und einfacher.




creator NOT IN ("lukas.ortner@tuwien.ac.at","michaela.dereani@tuwien.ac.at", "kurt.rosivatz@tuwien.ac.at") AND space = schulung AND type = comment

Alle Kommentare aus dem Bereich TU coLAB Schulung die NICHT von den 3 folgenden Nutzer_innen erstellt worden sind


Beinhaltet~

Der ~ Operator wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds mit dem angegebenen Wert übereinstimmt (entweder eine exakte Übereinstimmung oder eine ungefähre Übereinstimmung).

Der Operator ~ kann nur mit Textfeldern verwendet werden (z.B. Titel, Text)



title ~ colab

Suchen Sie alle Inhalte, bei dem der Titel das Wort colab enthält.


title ~ "colab*"

Suchen Sie alle Inhalte, bei denen der Titel eine Platzhalterübereinstimmung für das Wort colab enthält.


text ~ "colab hilfe"

Suchen Sie alle Inhalte, in deren Text das Wort colab und das Wort hilfe vorkommt.


Beinhaltet nicht!~

Der !~ Operator wird verwendet, um nach Inhalten zu suchen, bei denen der Wert des angegebenen Felds nicht mit dem angegebenen Wert übereinstimmt.

Der Operator ~ kann nur mit Textfeldern verwendet werden (z.B. Titel, Text)



space = HELP AND title !~ colab AND type = page

Suchen Sie alle Seiten aus dem Bereich TU coLAB Hilfe, in deren Titel sich nicht das Wort colab befindet.


Liste der ansprechbaren Felder


NameBeschreibungBeispielUnterstützte Operatoren
Ancestor

Suchen Sie nach allen Seiten, die Nachkommen einer bestimmten Elternseite sind. Dies inkludiert direkte untergeordnete Seiten und deren Nachkommen.


Bei Ancestor wird mit der ID der Seite gearbeitet, wenn Sie CQL-Abfragen auf eine spezifische Seite anwenden möchten brauchen Sie die Seiten-ID.

Diese erhalten Sie, nachdem Sie rechts oben auf der entsprechenden Seite die 3 Punkte geklickt haben und danach auf Seiteninformationen klicken.

Nun sehen Sie in der Adressleiste oben eine Nummer. Dies ist die ID der Seite.



ancestor = 4587931

Alle Nachkommen der angegeben Seite


  • =
  • !=
  • IN
  • NOT IN
Created

Suchen Sie nach Inhalten, die an, vor oder nach einem bestimmten Datum (oder Datumsbereich) erstellt wurden.

Sie müssen für das Format des Datums eines der folgenden Formate auswählen:

  • "yyyy/MM/dd"
  • "yyyy-MM-dd"


Folgende vorgefertigte Funktionen können in Zusammenhang mit Created benützt werden:

endOfDay(inc)

endOfMonth(inc)

endOfWeek(inc)

endOfYear(inc)

startOfDay(inc)

startOfMonth(inc)

startOfWeek(inc)

startOfYear(inc)


Wobei inc ein optionaler Inkrement von (+/-) ist

  • Wenn kein Vorzeichen angegeben wird, wird + angenommen.
  • y: Jahr, M: Monat, w: Woche, d: Tag


created > "2020-12-01" AND type = page

Alle Seiten, die seit 01. Dezember 2020 erstellt worden sind.


created > endOfWeek("-1w") AND type = page

Suchen Sie nach Seiten, die seit Ende letzter Woche erstellt worden sind.


created >= now("-6w") AND space = HELP

Sucht nach erstelltem Inhalt der letzten 6 Wochen im Bereich TU coLAB Hilfe


  • =
  • !=
  • >
  • >=
  • <
  • >=
Creator

Suchen Sie nach Inhalten, die von einem bestimmten Benutzer erstellt worden sind.

Sie können nach dem Benutzernamen des Benutzers suchen.

Mittels der Funktion currentUser() können Sie den/die aktuell angemeldeten Benutzer_in auswählen.


creator = "lukas.ortner@tuwien.ac.at" AND type = page

Erstellte Seiten von Lukas Ortner


creator = currentUser() AND type = page and created > now("-1w")


Sucht die Seiten vom aktuell eingeloggten Benutzer, die innerhalb der letzten 7 Tage erstellt worden sind.


  • =
  • =
  • IN
  • NOT IN
Contributor

Suchen Sie nach Inhalten, die von einem/r bestimmten Benutzer_in bearbeitet worden sind.

Sie können nach dem Benutzernamen des Benutzers suchen.

Mittels der Funktion currentUser() können Sie den/die aktuell angemeldeten Benutzer_in auswählen.


contributor = "lukas.ortner@tuwien.ac.at" AND type = page AND space = schulung

Sucht Seiten aus dem Bereich TU coLAB Schulungen, die von Lukas Ortnererstellt oder bearbeitet worden sind.


  • =
  • =
  • IN
  • NOT IN
LabelSuchen Sie nach Inhalten mit einem bestimmten Stichwort.


label = colabhilfe

Suchen Sie nach Inhalten mit dem Stichwort colabhilfe


  • =
  • !=
  • IN
  • NOT IN
Last modified

Suchen Sie nach Inhalten, die zuletzt an, vor oder nach einem bestimmten Datum (oder Datumsbereich) geändert wurden.

Sie müssen für das Format des Datums eines der folgenden Formate auswählen:

  • "yyyy/MM/dd"
  • "yyyy-MM-dd"


Folgende vorgefertigte Funktionen können in Zusammenhang mit Created benützt werden:

endOfDay(inc)

endOfMonth(inc)

endOfWeek(inc)

endOfYear(inc)

startOfDay(inc)

startOfMonth(inc)

startOfWeek(inc)

startOfYear(inc)


Wobei inc ein optionaler Inkrement von (+/-) ist

  • Wenn kein Vorzeichen angegeben wird, wird + angenommen.
  • y: Jahr, M: Monat, w: Woche, d: Tag


lastmodified > startOfYear()

Suchen Sie nach Inhalten, die zuletzt seit Jahresbeginn geändert wurden.


lastmodified > endOfWeek("-1w") AND type = page


Suchen Sie nach Seiten, die seit Ende letzter Woche geändert worden sind.


lastmodified >= "2020-12-24" AND lastmodified < "2021-01-02"


Suchen Sie nach Seiten, die zwischen 24. Dezember 2020 und 02. Januar 2021 geändert wurden.


  • =
  • !=
  • >
  • >=
  • <
  • >=
MacroSuchen Sie nach Inhalten, die eine Instanz des Makros mit dem angegebenen Namen im Inhalt enthalten.


macro in (toc,widget)

Suchen Sie nach Inhalten mit den Makros: Inhaltsverzeichnis oder Widget Makro


  • =
  • !=
  • IN
  • NOT IN
Mention

Suchen Sie nach Inhalten, die einen bestimmten Benutzer erwähnen.


Mittels der Funktion currentUser() können Sie den/die aktuell angemeldeten Benutzer_in auswählen.


mention = "lukas.ortner@tuwien.ac.at"

Finden Sie Inhalte, in denen Lukas Ortnererwähnt wird.


mention = currentUser()

Finden Sie Inhalte, in denen der aktuell angemeldete Benutzer erwähnt wird.


  • =
  • !=
  • IN
  • NOT IN
Space

Suchen Sie nach Inhalten, die sich in einem bestimmten Bereich befinden.

Sie können nach Titel und Schlüssel suchen.

  • Space key
  • Space title


space in (HELP,SCHULUNG) AND type = page

Sucht nach Seiten in den Bereichen TU coLAB Hilfe & TU coLAB Schulungen.


space.title ~ "TU coLAB Hilfe"


Sucht Sie nach Inhalten im Bereich mit dem angegebenen Titel. 

Beachten Sie hier wurde der Tilde (~) Operator angewendet.


space.key = HELP AND type = blogpost


Sucht nach Blogeinträgen im Bereich mit dem Bereichsschlüssel HELP (TU coLAB Hilfe)


  • =
  • !=
  • IN
  • NOT IN
Text

Suchen Sie nach Inhalten, die z.B. ein gewisses Wort enthalten.


text ~ colab AND space = help

Sucht nach Inhalten im Bereich TU coLAB Hilfe in denen das Wort colab vorkommt.


  • ~
  • !~
Title

Suchen Sie nach Inhalten nach Titel oder mit einem Titel, der bestimmten Text enthält.


title = "Digitalisierungsstrategie"

Sucht nach der Seite mit dem Titel "Digitalisierungsstrategie"


title ~ "Digitalisierung"

Sucht nach Seiten, die im Titel das Wort Digitalisierung beinhalten


  • =
  • !=
  • ~
  • !~
  • IN
  • NOT IN
Type

Suchen Sie nach Inhalten eines bestimmten Typs. Unterstützte Inhaltstypen sind:

NameBeschreibung
pageSeite
blogpostBlog-Eintrag
commentKommentar
attachmentAnhang



space = help AND type IN (blogpost, comment)

Sucht nach Inhalten des Typs Blog-Eintrag und Kommentar aus dem Bereich TU coLAB Hilfe


space = help AND type = page

Sucht nach allen Seiten aus dem Bereich TU coLAB Hilfe


  • =
  • !=
  • IN
  • NOT IN
WatcherSuchen Sie nach Inhalten, die eine bestimmte Benutzerin beobachtet. Sie können nach dem Benutzernamen des Benutzers/der Benutzerin suchen.


watcher = currentUser()

Suchen Sie nach Inhalten, die Sie gerade ansehen.


watcher = "lukas.ortner@tuwien.ac.at"

Suchen Sie nach Inhalten, die Lukas Ortner beobachtet.